wulkanowy-mirror/build.gradle

buildscript {
    ext.kotlin_version = '1.3.50'
    repositories {
        mavenCentral()
        google()
        jcenter()
        maven { url "https://plugins.gradle.org/m2/" }
        maven { url 'https://maven.fabric.io/public' }
    }
    dependencies {
        classpath "org.jetbrains.kotlin:kotlin-gradle-plugin:$kotlin_version"
        classpath 'com.android.tools.build:gradle:3.5.0'
        classpath 'com.google.gms:google-services:4.3.2'
        classpath "io.fabric.tools:gradle:1.31.0"
        classpath "com.github.triplet.gradle:play-publisher:2.4.1"
        classpath "org.sonarsource.scanner.gradle:sonarqube-gradle-plugin:2.7.1"
        classpath "gradle.plugin.com.star-zero.gradle:githook:1.1.0"
    }
}

project.ext.preDexLibs = !project.hasProperty("disablePreDex")
subprojects {
    project.plugins.whenPluginAdded { plugin ->
        if ("com.android.build.gradle.AppPlugin" == plugin.class.name) {
            project.android.dexOptions.preDexLibraries = rootProject.ext.preDexLibs
        } else if ("com.android.build.gradle.LibraryPlugin" == plugin.class.name) {
            project.android.dexOptions.preDexLibraries = rootProject.ext.preDexLibs
        }
    }
}

allprojects {
    repositories {
        mavenCentral()
        google()
        jcenter()
        maven { url 'https://jitpack.io' }
        maven { url "https://kotlin.bintray.com/kotlinx/" }
        maven { url "https://dl.bintray.com/mockito/maven" }
    }
}

task clean(type: Delete) {
    delete rootProject.buildDir
}